// Web_Server.idl,v 1.3 2000/06/19 23:38:57 schmidt Exp

module Web_Server
// = TITLE
// IDL schema definition for Web server interface.
{
  typedef sequence<octet> Chunk_Type;

  interface Content_Iterator
  {
    // This operation returns the next <chunk> of the
    // file starting at <offset>.  If there are
    // no more bindings, false is returned.
    boolean next_chunk (in unsigned long offset,
                        out Chunk_Type chunk);

    // This operation destroys the iterator.
    void destroy ();
  };

  exception Error_Result {
    // Status of the <get_iterator> operation.  These
    // values should map onto the normal HTTP
    // status values, e.g., 200 means success, 404
    // means "file not found," etc.
    short status;
 };

  struct Metadata_Type
  {
    // Modification date.
    string modification_date;

    // Type of content.
    string content_type;
  };

  interface Iterator_Factory
  {
    // This factory method returns a <Content_Iterator> that
    // can be used to read the <contents> associated with
    // <pathname> one ``chunk'' at a time.  The <metadata>
    // reports information about the <contents>.
    void get_iterator (in string pathname,
                       out Content_Iterator contents,
                       out Metadata_Type metadata)
      raises (Error_Result);
  };
};
